noctalia-git: initial PKGBUILD

2026-04-27 17:53:42 +02:00
parent 5c5d5c8004
commit 6f64fb1644
2 changed files with 89 additions and 18 deletions
@@ -1,11 +1,33 @@
 pkgbase = noctalia-git
-    pkgdesc = Placeholder for noctalia-git
-    pkgver = 0.0.0
-    pkgrel = 1
-    arch = any
-    url = https://github.com/noctalia-dev/noctalia
-    license = MIT
-    provides = noctalia
-    conflicts = noctalia
+        pkgdesc = Lightweight Wayland shell built directly on Wayland and OpenGL ES
+        pkgver = 5.0.0.r1029.gb3b0a511d
+        pkgrel = 1
+        url = https://github.com/noctalia-dev/noctalia-shell
+        arch = x86_64
+        license = MIT
+        makedepends = git
+        makedepends = meson
+        makedepends = ninja
+        makedepends = pkgconf
+        makedepends = wayland-protocols
+        depends = cairo
+        depends = curl
+        depends = fontconfig
+        depends = freetype2
+        depends = gcc-libs
+        depends = glibc
+        depends = libglvnd
+        depends = libpipewire
+        depends = libwebp
+        depends = libxkbcommon
+        depends = pam
+        depends = pango
+        depends = sdbus-cpp
+        depends = wayland
+        provides = noctalia
+        conflicts = noctalia
+        conflicts = noctalia-bin
+        source = noctalia::git+https://github.com/noctalia-dev/noctalia-shell.git#branch=v5
+        sha256sums = SKIP

-pkgname = noctalia-git
+pkgname = noctalia-git
@@ -1,15 +1,64 @@
+# Maintainer: Noctalia Team <team@noctalia.dev>
+
 pkgname=noctalia-git
-pkgver=0.0.0
+_pkgname=noctalia
+pkgver=5.0.0.r1029.gb3b0a511d
 pkgrel=1
-pkgdesc="Placeholder for noctalia-git"
-arch=('any')
-url="https://github.com/noctalia-dev/noctalia"
+pkgdesc='Lightweight Wayland shell built directly on Wayland and OpenGL ES'
+arch=('x86_64')
+url='https://github.com/noctalia-dev/noctalia-shell'
 license=('MIT')
+depends=(
+  'cairo'
+  'curl'
+  'fontconfig'
+  'freetype2'
+  'gcc-libs'
+  'glibc'
+  'libglvnd'
+  'libpipewire'
+  'libwebp'
+  'libxkbcommon'
+  'pam'
+  'pango'
+  'sdbus-cpp'
+  'wayland'
+)
+makedepends=(
+  'git'
+  'meson'
+  'ninja'
+  'pkgconf'
+  'wayland-protocols'
+)
 provides=('noctalia')
-conflicts=('noctalia')
-source=()
-sha256sums=()
+conflicts=('noctalia' 'noctalia-bin')
+source=("${_pkgname}::git+${url}.git#branch=v5")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${_pkgname}"
+
+  local version
+  version="$(sed -n "s/^  version: '\([^']*\)',/\1/p" meson.build)"
+  printf '%s.r%s.g%s' "${version}" "$(git rev-list --count HEAD)" "$(git rev-parse --short=9 HEAD)"
+}
+
+build() {
+  meson setup "${_pkgname}" build-release \
+    --prefix=/usr \
+    --buildtype=plain \
+    -Doptimization=3 \
+    -Db_ndebug=true \
+    -Db_lto=true \
+    --wrap-mode=nodownload
+  meson compile -C build-release
+}

 package() {
-  install -Dm644 /dev/null "$pkgdir/usr/share/doc/$pkgname/placeholder"
-}
+  meson install -C build-release --destdir "${pkgdir}"
+
+  install -Dm644 "${_pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm644 "${_pkgname}/README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
+  install -Dm644 "${_pkgname}/CONFIG.md" "${pkgdir}/usr/share/doc/${pkgname}/CONFIG.md"
+}