noctalia-git: initial PKGBUILD

.SRCINFO

@@ -1,11 +1,33 @@
 pkgbase = noctalia-git
-    pkgdesc = Placeholder for noctalia-git
+        pkgdesc = Lightweight Wayland shell built directly on Wayland and OpenGL ES
-    pkgver = 0.0.0
+        pkgver = 5.0.0.r1029.gb3b0a511d
-    pkgrel = 1
+        pkgrel = 1
-    arch = any
+        url = https://github.com/noctalia-dev/noctalia-shell
-    url = https://github.com/noctalia-dev/noctalia
+        arch = x86_64
-    license = MIT
+        license = MIT
-    provides = noctalia
+        makedepends = git
-    conflicts = noctalia
+        makedepends = meson
+        makedepends = ninja
+        makedepends = pkgconf
+        makedepends = wayland-protocols
+        depends = cairo
+        depends = curl
+        depends = fontconfig
+        depends = freetype2
+        depends = gcc-libs
+        depends = glibc
+        depends = libglvnd
+        depends = libpipewire
+        depends = libwebp
+        depends = libxkbcommon
+        depends = pam
+        depends = pango
+        depends = sdbus-cpp
+        depends = wayland
+        provides = noctalia
+        conflicts = noctalia
+        conflicts = noctalia-bin
+        source = noctalia::git+https://github.com/noctalia-dev/noctalia-shell.git#branch=v5
+        sha256sums = SKIP
 
-pkgname = noctalia-git
+pkgname = noctalia-git

PKGBUILD

@@ -1,15 +1,64 @@
+# Maintainer: Noctalia Team <team@noctalia.dev>
+
 pkgname=noctalia-git
-pkgver=0.0.0
+_pkgname=noctalia
+pkgver=5.0.0.r1029.gb3b0a511d
 pkgrel=1
-pkgdesc="Placeholder for noctalia-git"
+pkgdesc='Lightweight Wayland shell built directly on Wayland and OpenGL ES'
-arch=('any')
+arch=('x86_64')
-url="https://github.com/noctalia-dev/noctalia"
+url='https://github.com/noctalia-dev/noctalia-shell'
 license=('MIT')
+depends=(
+  'cairo'
+  'curl'
+  'fontconfig'
+  'freetype2'
+  'gcc-libs'
+  'glibc'
+  'libglvnd'
+  'libpipewire'
+  'libwebp'
+  'libxkbcommon'
+  'pam'
+  'pango'
+  'sdbus-cpp'
+  'wayland'
+)
+makedepends=(
+  'git'
+  'meson'
+  'ninja'
+  'pkgconf'
+  'wayland-protocols'
+)
 provides=('noctalia')
-conflicts=('noctalia')
+conflicts=('noctalia' 'noctalia-bin')
-source=()
+source=("${_pkgname}::git+${url}.git#branch=v5")
-sha256sums=()
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${_pkgname}"
+
+  local version
+  version="$(sed -n "s/^  version: '\([^']*\)',/\1/p" meson.build)"
+  printf '%s.r%s.g%s' "${version}" "$(git rev-list --count HEAD)" "$(git rev-parse --short=9 HEAD)"
+}
+
+build() {
+  meson setup "${_pkgname}" build-release \
+    --prefix=/usr \
+    --buildtype=plain \
+    -Doptimization=3 \
+    -Db_ndebug=true \
+    -Db_lto=true \
+    --wrap-mode=nodownload
+  meson compile -C build-release
+}
 
 package() {
-  install -Dm644 /dev/null "$pkgdir/usr/share/doc/$pkgname/placeholder"
+  meson install -C build-release --destdir "${pkgdir}"
-}
+
+  install -Dm644 "${_pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm644 "${_pkgname}/README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
+  install -Dm644 "${_pkgname}/CONFIG.md" "${pkgdir}/usr/share/doc/${pkgname}/CONFIG.md"
+}